Find I2C OLED Address and Display original image¶

Step_1: Address written on the devices¶

	Where/How	Address Dec	Hex	Binary(8bit)	(7bit) +R/W	8bit
Step_1	on Device		0x78	-	-
Step_2	I2C Scanner

Step_2: Find address by i2c_scanner¶

Arduino Sketch¶

Ref. classpage_hello.I2C.ino

#include <Wire.h>

void setup() {
   Serial.begin(115200);
   Wire.begin();
   }

uint8_t address,count;

void loop() {
   count = 0;
   Serial.println("start scan ...");
   for (address = 1; address < 127; address++) {
      Wire.beginTransmission (address);
      if (Wire.endTransmission () == 0) {
         count += 1;
         Serial.print("   found ");
         Serial.print(address,DEC);
         Serial.print(" (0x");
         Serial.print(address,HEX);
         Serial.println (")");
         }
      }
   if (count == 0)
      Serial.println("   no devices found");
   delay(1000);
   }

Connection¶

pinout

Result¶

Convert Hex to Binary¶

Binary to Hex converter

	Where/How	Address Dec	Hex	Binary(8bit)	(7bit) +R/W	8bit
Step_1	on Device		0x78	-	-	01111000
Step_2	I2C Scanner	60	0X3C	00111100	0111100_+0	01111000

Ref. 7-bit, 8-bit, and 10-bit I2C Slave Addressing
The eighth bit is the read/write flag
1: read
0: write

Ref. I2C addresses! The List

All I2C addresses here are in 7-bit format

0x78 0x79 0x7A 0x7B - Reserved for 10-bit I2C Addressing
0x7C 0x7D 0x7E 0x7F - Reserved for Future Purposes

OLED Program from Arduino IDE¶

Library¶

Sample sketch¶

Example -> Adafruit SSD1306 -> ssd1306_128x64_i2c

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
// The pins for I2C are defined by the Wire-library.
// On an arduino UNO:       A4(SDA), A5(SCL)
// On an arduino MEGA 2560: 20(SDA), 21(SCL)
// On an arduino LEONARDO:   2(SDA),  3(SCL), ...
#define OLED_RESET     4 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3D ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16
static const unsigned char PROGMEM logo_bmp[] =
{ B00000000, B11000000,
  B00000001, B11000000,
  B00000001, B11000000,
  B00000011, B11100000,
  B11110011, B11100000,
  B11111110, B11111000,
  B01111110, B11111111,
  B00110011, B10011111,
  B00011111, B11111100,
  B00001101, B01110000,
  B00011011, B10100000,
  B00111111, B11100000,
  B00111111, B11110000,
  B01111100, B11110000,
  B01110000, B01110000,
  B00000000, B00110000 };

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  display.display();
  delay(2000); // Pause for 2 seconds

  // Clear the buffer
  display.clearDisplay();

  // Draw a single pixel in white
  display.drawPixel(10, 10, SSD1306_WHITE);

  // Show the display buffer on the screen. You MUST call display() after
  // drawing commands to make them visible on screen!
  display.display();
  delay(2000);
  // display.display() is NOT necessary after every single drawing command,
  // unless that's what you want...rather, you can batch up a bunch of
  // drawing operations and then update the screen all at once by calling
  // display.display(). These examples demonstrate both approaches...

  testdrawline();      // Draw many lines

  testdrawrect();      // Draw rectangles (outlines)

  testfillrect();      // Draw rectangles (filled)

  testdrawcircle();    // Draw circles (outlines)

  testfillcircle();    // Draw circles (filled)

  testdrawroundrect(); // Draw rounded rectangles (outlines)

  testfillroundrect(); // Draw rounded rectangles (filled)

  testdrawtriangle();  // Draw triangles (outlines)

  testfilltriangle();  // Draw triangles (filled)

  testdrawchar();      // Draw characters of the default font

  testdrawstyles();    // Draw 'stylized' characters

  testscrolltext();    // Draw scrolling text

  testdrawbitmap();    // Draw a small bitmap image

  // Invert and restore display, pausing in-between
  display.invertDisplay(true);
  delay(1000);
  display.invertDisplay(false);
  delay(1000);

  testanimate(logo_bmp, LOGO_WIDTH, LOGO_HEIGHT); // Animate bitmaps
}

void loop() {
}

void testdrawline() {
  int16_t i;

  display.clearDisplay(); // Clear display buffer

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, 0, i, display.height()-1, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn line
    delay(1);
  }
  for(i=0; i<display.height(); i+=4) {
    display.drawLine(0, 0, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(0, display.height()-1, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=display.width()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.height(); i+=4) {
    display.drawLine(display.width()-1, 0, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=0; i<display.width(); i+=4) {
    display.drawLine(display.width()-1, 0, i, display.height()-1, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000); // Pause for 2 seconds
}

void testdrawrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=2) {
    display.drawRect(i, i, display.width()-2*i, display.height()-2*i, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testfillrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=3) {
    // The INVERSE color is used so rectangles alternate white/black
    display.fillRect(i, i, display.width()-i*2, display.height()-i*2, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testdrawcircle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=2) {
    display.drawCircle(display.width()/2, display.height()/2, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillcircle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=3) {
    // The INVERSE color is used so circles alternate white/black
    display.fillCircle(display.width() / 2, display.height() / 2, i, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn circle
    delay(1);
  }

  delay(2000);
}

void testdrawroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    // The INVERSE color is used so round-rects alternate white/black
    display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawtriangle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=5) {
    display.drawTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfilltriangle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=5) {
    // The INVERSE color is used so triangles alternate white/black
    display.fillTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawchar(void) {
  display.clearDisplay();

  display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE); // Draw white text
  display.setCursor(0, 0);     // Start at top-left corner
  display.cp437(true);         // Use full 256 char 'Code Page 437' font

  // Not all the characters will fit on the display. This is normal.
  // Library will draw what it can and the rest will be clipped.
  for(int16_t i=0; i<256; i++) {
    if(i == '\n') display.write(' ');
    else          display.write(i);
  }

  display.display();
  delay(2000);
}

void testdrawstyles(void) {
  display.clearDisplay();

  display.setTextSize(1);             // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);        // Draw white text
  display.setCursor(0,0);             // Start at top-left corner
  display.println(F("Hello, world!"));

  display.setTextColor(SSD1306_BLACK, SSD1306_WHITE); // Draw 'inverse' text
  display.println(3.141592);

  display.setTextSize(2);             // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.print(F("0x")); display.println(0xDEADBEEF, HEX);

  display.display();
  delay(2000);
}

void testscrolltext(void) {
  display.clearDisplay();

  display.setTextSize(2); // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(10, 0);
  display.println(F("scroll"));
  display.display();      // Show initial text
  delay(100);

  // Scroll in various directions, pausing in-between:
  display.startscrollright(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrollleft(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrolldiagright(0x00, 0x07);
  delay(2000);
  display.startscrolldiagleft(0x00, 0x07);
  delay(2000);
  display.stopscroll();
  delay(1000);
}

void testdrawbitmap(void) {
  display.clearDisplay();

  display.drawBitmap(
    (display.width()  - LOGO_WIDTH ) / 2,
    (display.height() - LOGO_HEIGHT) / 2,
    logo_bmp, LOGO_WIDTH, LOGO_HEIGHT, 1);
  display.display();
  delay(1000);
}

#define XPOS   0 // Indexes into the 'icons' array in function below
#define YPOS   1
#define DELTAY 2

void testanimate(const uint8_t *bitmap, uint8_t w, uint8_t h) {
  int8_t f, icons[NUMFLAKES][3];

  // Initialize 'snowflake' positions
  for(f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
    icons[f][YPOS]   = -LOGO_HEIGHT;
    icons[f][DELTAY] = random(1, 6);
    Serial.print(F("x: "));
    Serial.print(icons[f][XPOS], DEC);
    Serial.print(F(" y: "));
    Serial.print(icons[f][YPOS], DEC);
    Serial.print(F(" dy: "));
    Serial.println(icons[f][DELTAY], DEC);
  }

  for(;;) { // Loop forever...
    display.clearDisplay(); // Clear the display buffer

    // Draw each snowflake:
    for(f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], bitmap, w, h, SSD1306_WHITE);
    }

    display.display(); // Show the display buffer on the screen
    delay(200);        // Pause for 1/10 second

    // Then update coordinates of each flake...
    for(f=0; f< NUMFLAKES; f++) {
      icons[f][YPOS] += icons[f][DELTAY];
      // If snowflake is off the bottom of the screen...
      if (icons[f][YPOS] >= display.height()) {
        // Reinitialize to a random position, just off the top
        icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
        icons[f][YPOS]   = -LOGO_HEIGHT;
        icons[f][DELTAY] = random(1, 6);
      }
    }
  }
}

Display original image¶

Ref. Display Images on OLED Display

Generate code from your image¶

site: Image2cpp ¶

image:¶

Setting¶

Attention

Canvas size/s 64x64
Brightness threshold　250

Code¶

const unsigned char myBitmap [] PROGMEM = {
    // 'FabLabLannai_Logo2022-tate-w (1), 64x64px
    0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
    0xff, 0xff, 0xff, 0xe0, 0x07, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0x00, 0x01, 0xff, 0xff, 0xff,
    0xff, 0xff, 0xfe, 0x01, 0x80, 0xff, 0xff, 0xff, 0xff, 0xff, 0xfc, 0x07, 0xc0, 0x3f, 0xff, 0xff,
    0xff, 0xff, 0xf8, 0x00, 0x10, 0x1f, 0xff, 0xff, 0xff, 0xff, 0xf0, 0x00, 0x0c, 0x1f, 0xff, 0xff,
    0xff, 0xff, 0xe0, 0x80, 0x06, 0x0f, 0xff, 0xff, 0xff, 0xff, 0xe3, 0xc0, 0x07, 0x87, 0xff, 0xff,
    0xff, 0xff, 0xc7, 0xc0, 0x07, 0xc7, 0xff, 0xff, 0xff, 0xff, 0xc7, 0xe0, 0x0f, 0xc3, 0xff, 0xff,
    0xff, 0xff, 0xc7, 0xf0, 0x1f, 0xc3, 0xff, 0xff, 0xff, 0xff, 0x87, 0xff, 0xff, 0xc3, 0xff, 0xff,
    0xff, 0xff, 0x87, 0x3f, 0xf8, 0xc3, 0xff, 0xff, 0xff, 0xff, 0x86, 0x0f, 0xf0, 0x03, 0xff, 0xff,
    0xff, 0xff, 0x84, 0x07, 0xe0, 0x03, 0xff, 0xff, 0xff, 0xff, 0x84, 0x03, 0xc0, 0x03, 0xff, 0xff,
    0xff, 0xff, 0x84, 0x03, 0xc0, 0x03, 0xff, 0xff, 0xff, 0xff, 0x84, 0x03, 0x80, 0x03, 0xff, 0xff,
    0xff, 0xff, 0xc4, 0x01, 0x80, 0x43, 0xff, 0xff, 0xff, 0xff, 0xc6, 0x01, 0x80, 0x47, 0xff, 0xff,
    0xff, 0xff, 0xc7, 0x03, 0x80, 0xc7, 0xff, 0xff, 0xff, 0xff, 0xe1, 0x03, 0xc1, 0x87, 0xff, 0xff,
    0xff, 0xff, 0xf0, 0x07, 0xe6, 0x0f, 0xff, 0xff, 0xff, 0xff, 0xf0, 0x07, 0xf8, 0x1f, 0xff, 0xff,
    0xff, 0xff, 0xf8, 0x07, 0xf0, 0x3f, 0xff, 0xff, 0xff, 0xff, 0xfc, 0x03, 0x80, 0x7f, 0xff, 0xff,
    0xff, 0xff, 0xff, 0x01, 0x00, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0x80, 0x03, 0xff, 0xff, 0xff,
    0xff, 0xff, 0xff, 0xf0, 0x1f, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
    0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff,
    0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc0, 0x7f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff,
    0xc7, 0xff, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc7, 0xfd, 0xf8, 0xde, 0x3f, 0xfb, 0xf1, 0xbf,
    0xc0, 0x30, 0x08, 0x06, 0x3f, 0xe0, 0x10, 0x0f, 0xc0, 0x20, 0x08, 0x00, 0x3f, 0xc0, 0x10, 0x07,
    0xc0, 0x00, 0x08, 0x00, 0x3f, 0x80, 0x10, 0x03, 0xc7, 0xc7, 0x88, 0x70, 0x3f, 0x0e, 0x11, 0xe3,
    0xc7, 0x87, 0x88, 0xf0, 0x3f, 0x0f, 0x11, 0xe1, 0xc7, 0x87, 0x88, 0xf0, 0x3f, 0x1f, 0x11, 0xe1,
    0xc7, 0xc7, 0x88, 0xf0, 0x3f, 0x0f, 0x11, 0xe3, 0xc7, 0xc3, 0x08, 0x60, 0x00, 0x06, 0x10, 0xc3,
    0xc7, 0x20, 0x08, 0x00, 0x00, 0x00, 0x10, 0x03, 0xc7, 0x00, 0x08, 0x02, 0x00, 0x40, 0x10, 0x07,
    0xc6, 0x10, 0x88, 0x86, 0x00, 0x61, 0x11, 0x0f, 0xc4, 0x20, 0x08, 0x06, 0x01, 0xc0, 0x11, 0xff,
    0xc0, 0x60, 0x08, 0x02, 0x00, 0x80, 0x11, 0xff, 0xc0, 0xc0, 0x08, 0x02, 0x00, 0x80, 0x11, 0xff,
    0xc1, 0xc7, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff, 0xc1, 0x87, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff,
    0xc0, 0x07, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff, 0xc0, 0x47, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff,
    0xc4, 0x03, 0x08, 0xe2, 0x38, 0x86, 0x11, 0xff, 0xc6, 0x00, 0x08, 0xe2, 0x38, 0x80, 0x11, 0xff,
    0xc7, 0x00, 0x08, 0xe2, 0x38, 0xc0, 0x11, 0xff, 0xff, 0x00, 0xff, 0xff, 0xff, 0xf3, 0xff, 0xff,
    0xff, 0x87, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
    0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff
};

Arduino Sketch¶

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

#define OLED_RESET 4
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define LOGO_HEIGHT   64
#define LOGO_WIDTH    64



//image bitmap data
const unsigned char myBitmap [] PROGMEM = {
  // 'FabLabLannai_Logo2022-tate-w (1), 64x64px
  0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
  0xff, 0xff, 0xff, 0xe0, 0x07, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0x00, 0x01, 0xff, 0xff, 0xff,
  0xff, 0xff, 0xfe, 0x01, 0x80, 0xff, 0xff, 0xff, 0xff, 0xff, 0xfc, 0x07, 0xc0, 0x3f, 0xff, 0xff,
  0xff, 0xff, 0xf8, 0x00, 0x10, 0x1f, 0xff, 0xff, 0xff, 0xff, 0xf0, 0x00, 0x0c, 0x1f, 0xff, 0xff,
  0xff, 0xff, 0xe0, 0x80, 0x06, 0x0f, 0xff, 0xff, 0xff, 0xff, 0xe3, 0xc0, 0x07, 0x87, 0xff, 0xff,
  0xff, 0xff, 0xc7, 0xc0, 0x07, 0xc7, 0xff, 0xff, 0xff, 0xff, 0xc7, 0xe0, 0x0f, 0xc3, 0xff, 0xff,
  0xff, 0xff, 0xc7, 0xf0, 0x1f, 0xc3, 0xff, 0xff, 0xff, 0xff, 0x87, 0xff, 0xff, 0xc3, 0xff, 0xff,
  0xff, 0xff, 0x87, 0x3f, 0xf8, 0xc3, 0xff, 0xff, 0xff, 0xff, 0x86, 0x0f, 0xf0, 0x03, 0xff, 0xff,
  0xff, 0xff, 0x84, 0x07, 0xe0, 0x03, 0xff, 0xff, 0xff, 0xff, 0x84, 0x03, 0xc0, 0x03, 0xff, 0xff,
  0xff, 0xff, 0x84, 0x03, 0xc0, 0x03, 0xff, 0xff, 0xff, 0xff, 0x84, 0x03, 0x80, 0x03, 0xff, 0xff,
  0xff, 0xff, 0xc4, 0x01, 0x80, 0x43, 0xff, 0xff, 0xff, 0xff, 0xc6, 0x01, 0x80, 0x47, 0xff, 0xff,
  0xff, 0xff, 0xc7, 0x03, 0x80, 0xc7, 0xff, 0xff, 0xff, 0xff, 0xe1, 0x03, 0xc1, 0x87, 0xff, 0xff,
  0xff, 0xff, 0xf0, 0x07, 0xe6, 0x0f, 0xff, 0xff, 0xff, 0xff, 0xf0, 0x07, 0xf8, 0x1f, 0xff, 0xff,
  0xff, 0xff, 0xf8, 0x07, 0xf0, 0x3f, 0xff, 0xff, 0xff, 0xff, 0xfc, 0x03, 0x80, 0x7f, 0xff, 0xff,
  0xff, 0xff, 0xff, 0x01, 0x00, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0x80, 0x03, 0xff, 0xff, 0xff,
  0xff, 0xff, 0xff, 0xf0, 0x1f, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
  0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff,
  0xc0, 0x3f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc0, 0x7f, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff,
  0xc7, 0xff, 0xf8, 0xfe, 0x3f, 0xff, 0xf1, 0xff, 0xc7, 0xfd, 0xf8, 0xde, 0x3f, 0xfb, 0xf1, 0xbf,
  0xc0, 0x30, 0x08, 0x06, 0x3f, 0xe0, 0x10, 0x0f, 0xc0, 0x20, 0x08, 0x00, 0x3f, 0xc0, 0x10, 0x07,
  0xc0, 0x00, 0x08, 0x00, 0x3f, 0x80, 0x10, 0x03, 0xc7, 0xc7, 0x88, 0x70, 0x3f, 0x0e, 0x11, 0xe3,
  0xc7, 0x87, 0x88, 0xf0, 0x3f, 0x0f, 0x11, 0xe1, 0xc7, 0x87, 0x88, 0xf0, 0x3f, 0x1f, 0x11, 0xe1,
  0xc7, 0xc7, 0x88, 0xf0, 0x3f, 0x0f, 0x11, 0xe3, 0xc7, 0xc3, 0x08, 0x60, 0x00, 0x06, 0x10, 0xc3,
  0xc7, 0x20, 0x08, 0x00, 0x00, 0x00, 0x10, 0x03, 0xc7, 0x00, 0x08, 0x02, 0x00, 0x40, 0x10, 0x07,
  0xc6, 0x10, 0x88, 0x86, 0x00, 0x61, 0x11, 0x0f, 0xc4, 0x20, 0x08, 0x06, 0x01, 0xc0, 0x11, 0xff,
  0xc0, 0x60, 0x08, 0x02, 0x00, 0x80, 0x11, 0xff, 0xc0, 0xc0, 0x08, 0x02, 0x00, 0x80, 0x11, 0xff,
  0xc1, 0xc7, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff, 0xc1, 0x87, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff,
  0xc0, 0x07, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff, 0xc0, 0x47, 0x88, 0xe2, 0x38, 0x0f, 0x11, 0xff,
  0xc4, 0x03, 0x08, 0xe2, 0x38, 0x86, 0x11, 0xff, 0xc6, 0x00, 0x08, 0xe2, 0x38, 0x80, 0x11, 0xff,
  0xc7, 0x00, 0x08, 0xe2, 0x38, 0xc0, 0x11, 0xff, 0xff, 0x00, 0xff, 0xff, 0xff, 0xf3, 0xff, 0xff,
  0xff, 0x87, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff,
  0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff
};

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3D for 128x64
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  testdrawbitmap();    // Draw the required image
}

void loop() {
}

void testdrawbitmap(void) {
  display.clearDisplay();

  display.drawBitmap(
    (display.width()  - LOGO_WIDTH ) / 2,
    (display.height() - LOGO_HEIGHT) / 2,
   myBitmap , LOGO_WIDTH, LOGO_HEIGHT, 1);
  display.display();
  delay(1000);
}

Show¶

Last update: April 29, 2022

Find I2C OLED Address and Display original image¶

Step_1: Address written on the devices¶

Step_2: Find address by i2c_scanner¶

Arduino Sketch¶

Connection¶

Result¶

Convert Hex to Binary¶

OLED Program from Arduino IDE¶

Library¶

Sample sketch¶

Display original image¶

Generate code from your image¶

site: Image2cpp¶

image:¶

Setting¶

Code¶

Arduino Sketch¶

Show¶

site: Image2cpp ¶