const int    BAUD_RATE = 115200;
const int    LEDS[]    = {16, 17, 26};
const int    NB_LEDS   = 3;

const int T_SUCCESSIVE   = 400;
const int T_CLIGNOTEMENT = 500;
const int T_VAGUE        = 280;
const int T_SOS          = 180;

int  seqActive    = 0;
int  etape        = 0;
bool bascule      = false;
unsigned long tDernier = 0;

const int VAGUE[]     = {0, 1, 2, 1};
const int VAGUE_LEN   = 4;
const int SOS_MOTIF[] = {1,0,1,0,1,0,0, 3,0,3,0,3,0,0, 1,0,1,0,1,0,0,0};
const int SOS_LEN     = sizeof(SOS_MOTIF) / sizeof(SOS_MOTIF[0]);

String inputLine = "";

void ledSet(int i, bool on) { digitalWrite(LEDS[i], on ? HIGH : LOW); }
void toutEteindre() { for (int i=0;i<NB_LEDS;i++) ledSet(i,false); }
void toutAllumer()  { for (int i=0;i<NB_LEDS;i++) ledSet(i,true);  }

void envoyerEtat() {
  String msg = "LEDS:";
  for (int i = 0; i < NB_LEDS; i++) {
    msg += (digitalRead(LEDS[i]) == HIGH) ? "1" : "0";
    if (i < NB_LEDS - 1) msg += ",";
  }
  Serial.println(msg);
}

void traiterCommande(String cmd) {
  cmd.trim();
  Serial.print("CMD: "); Serial.println(cmd);
  if (cmd == "STOP") {
    seqActive = 0; etape = 0;
    toutEteindre(); envoyerEtat();
  } else if (cmd.startsWith("SEQ:")) {
    int seq = cmd.substring(4).toInt();
    if (seq >= 1 && seq <= 4) {
      seqActive = seq; etape = 0; bascule = false;
      tDernier = millis(); toutEteindre(); envoyerEtat();
    }
  }
}

void lireSerial() {
  while (Serial.available()) {
    char c = (char)Serial.read();
    if (c == '\n') {
      if (inputLine.length() > 0) { traiterCommande(inputLine); inputLine = ""; }
    } else if (c != '\r') { inputLine += c; }
  }
}

void executerSequence() {
  unsigned long now = millis();
  switch (seqActive) {
    case 1:
      if (now - tDernier >= T_SUCCESSIVE) {
        toutEteindre(); ledSet(etape % NB_LEDS, true);
        etape++; tDernier = now; envoyerEtat();
      } break;
    case 2:
      if (now - tDernier >= T_CLIGNOTEMENT) {
        bascule = !bascule;
        bascule ? toutAllumer() : toutEteindre();
        tDernier = now; envoyerEtat();
      } break;
    case 3:
      if (now - tDernier >= T_VAGUE) {
        toutEteindre(); ledSet(VAGUE[etape % VAGUE_LEN], true);
        etape++; tDernier = now; envoyerEtat();
      } break;
    case 4: {
      int unite = SOS_MOTIF[etape % SOS_LEN];
      unsigned long duree = (unsigned long)(unite > 0 ? unite : 1) * T_SOS;
      if (now - tDernier >= duree) {
        (unite > 0) ? toutAllumer() : toutEteindre();
        etape++; tDernier = now; envoyerEtat();
      } break;
    }
  }
}

void setup() {
  Serial.begin(BAUD_RATE);
  for (int i = 0; i < NB_LEDS; i++) {
    pinMode(LEDS[i], OUTPUT);
    digitalWrite(LEDS[i], LOW);
  }
  delay(300);
  Serial.println("READY");
}

void loop() {
  lireSerial();
  if (seqActive > 0) executerSequence();
}