Week 9: Input Devices

Assignments

Group Assignment

• Characterize the design rules for your in-house PCB production process
• Document the settings for your machine
• Reflect on the individual page what you learned

Individual Assignment

• Measure something: add a sensor to a microcontroller board that you have designed and read it

AD8232 Heart Monitor

After running into issues with the MAX30102, I decided to work with the AD8232 Heart Monitor instead.

This sensor is larger and probably will not fit into my final wearable design, but it still allowed me to learn how ECG signals are captured and processed.

The first step was understanding the pinout and how to correctly wire the module.

I connected GND to the XIAO ground pin, 3.3V to the 3.3V supply, and the signal output to D0.

The LO+ and LO- pins were connected to digital pins D1 and D2 to detect whether the electrodes were properly attached.

Programming the Sensor

The code reads the ECG signal, calculates BPM values and detects significant increases relative to a baseline heart rate.

If the BPM rises above the defined threshold, an LED starts blinking as an alert indicator.

#include <avr/io.h>

const int ECG_PIN = A0;
const int LO_MAS = 2;
const int LO_MENOS = 3;
const int LED_PIN = D6;

int threshold = 550;

bool lastBeat = false;

unsigned long lastBeatTime = 0;

int bpmArray[5] = {0,0,0,0,0};

int bpmIndex = 0;

int baselineBPM = 75;

int aumento = 10;

bool alerta = false;

unsigned long lastBlink = 0;

bool ledState = false;

void setup() {

  Serial.begin(115200);

  pinMode(LO_MAS, INPUT);

  pinMode(LO_MENOS, INPUT);

  pinMode(LED_PIN, OUTPUT);

}

void loop() {

  if (digitalRead(LO_MAS) == 1 ||
      digitalRead(LO_MENOS) == 1) {

    Serial.println("Electrodos desconectados");

    digitalWrite(LED_PIN, LOW);

    return;

  }

  int signal = analogRead(ECG_PIN);

  if (signal > threshold && !lastBeat) {

    unsigned long currentTime = millis();

    if (currentTime - lastBeatTime > 600) {

      if (lastBeatTime != 0) {

        int bpm =
        60000 / (currentTime - lastBeatTime);

        if (bpm > 40 && bpm < 100) {

          bpmArray[bpmIndex] = bpm;

          bpmIndex = (bpmIndex + 1) % 5;

          int sum = 0;

          for (int i = 0; i < 5; i++) {

            sum += bpmArray[i];

          }

          int avgBPM = sum / 5;

          Serial.print("BPM promedio: ");

          Serial.println(avgBPM);

          if (avgBPM > baselineBPM + aumento) {

            alerta = true;

            Serial.println("AUMENTO DETECTADO");

          }

          else {

            alerta = false;

          }

        }

      }

      lastBeatTime = currentTime;

    }

    lastBeat = true;

  }

  if (signal < threshold) {

    lastBeat = false;

  }

  if (alerta) {

    if (millis() - lastBlink > 500) {

      ledState = !ledState;

      digitalWrite(LED_PIN, ledState);

      lastBlink = millis();

    }

  }

  else {

    digitalWrite(LED_PIN, LOW);

  }

  delay(5);

}