Input Devices

Learning Objectives

Assignments

Learning Section

Individual Assignments

Input Devices

Step Response/ Capacitive Touch

Rotary Encoder

The rotary encoder generates (when rotating) two square waves on pins A (CLK) and B (DT) with 90° out of phase as shown in the figure below:

Since the normal state of pin A (CLK) and pin B (DT) are logic high we've to detect falling (transition from high to low) of one of them, here pin A is used to detect the movement of the rotary encoder in both directions (falling of pin A signal). Direction of rotation can be detected by knowing the status of pin B, if pin B is logic high this means the direction of rotation is clockwise (CW), and if pin B is logic low this means the direction of rotation is counter clockwise (CCW).

SAMD 21

Designing the Microcontroller Board

I decided to try something which involved buttons, sliders and enncoders for my final project - Symphoni The Record Player. But after seeing the class, I was amused by the capacitive touch and its capabilities. Therefore I decided my sensors for the week - Capacitive Touch Slider and Rotary Encoder.

I decided to use a 5 Capacitive Pad slider with a rotary encoder. And I decided to explore a new microcontroller - SAMD21 E17A.

I refered to some previous works of students who used capacitive touch and SAMD21

• JOGIN DOC - IPOD Track Wheel
• ABEL DOC - Linear Soft Pot
• Matt Doc - 8x8 Touch Pad



I refered to these documentations and studied about different types of Capacitive touch sensors and how they work. I studied about how these sensors work, and then Saheen told me that the board I chose, already has QTouch capibilities

I studied about how QTouch works on SAMD21 E17, the SAMD21 has specific pins called PTC pins to control

• ST-Touch
• Circuits and Techniques for Implementing Capacitive Touch Sensing

Peripheral Touch Controller (PTC)

The QTouch® Peripheral Touch Controller (PTC) offers built-in hardware for capacitive touch measurement on sensors that function as buttons, sliders, and wheels. The PTC has been designed to perform capacitive touch acquisition on sensors independently from the CPU, resulting in low CPU utilization and reduced power consumption.

The WS2812B uses 5V but my MCU uses 3.3 V logic level, therefore I needed the 5V output. So I had to make a logic level shifter. So I learned more about Logic Level Shifter.

I refered to this documentation Logic Level Shifters

After going back to the documentation, I realised that I had missed out on some essential connections on the board.

The device has several different power supply pins:

• VDDIO: Powers I/O lines, OSC8M and XOSC. Voltage is 1.62V to 3.63V.
• VDDIN: Powers I/O lines and the internal regulator. Voltage is 1.62V to 3.63V.
• VDDANA: Powers I/O lines and the ADC, AC, DAC, PTC, OSCULP32K, OSC32K, XOSC32K. Voltage is 1.62V to 3.63V.
• VDDCORE: Internal regulated voltage output. Powers the core, memories, peripherals, FDPLL96M, and DFLL48M. Voltage is 1.2V.

Programing TouchNav(SAMD21 Board)

To program the SAMD21 Board using Arduino IDE, we need to add the FAB SAMD Board to the Board Manager

To install, simply add the following URL to "Additional Boards Manager URLs" in the Arduino IDE: https://raw.githubusercontent.com/qbolsee/ArduinoCore-fab-sam/master/json/package_Fab_SAM_index.json

Install the board using the Board Manager

Blink

// the setup function runs once when you press reset or power the board
void setup() {
  // initialize builtin LED at pin 7 as an output.
  pinMode(7, OUTPUT);
}

// the loop function runs over and over again forever
void loop() {
  digitalWrite(7, HIGH);  // turn the LED on (HIGH is the voltage level)
  delay(1000);                      // wait for a second
  digitalWrite(7, LOW);   // turn the LED off by making the voltage LOW
  delay(1000);                      // wait for a second
}
								

SAMD21 Serial Demo

void setup() {
  SerialUSB.begin(115200);
}

#define max_buffer 25

void loop() {
  static char chr;
  static char buffer[max_buffer] = { 0 };
  static int index;
  if (SerialUSB.available()) {
    chr = SerialUSB.read();
    SerialUSB.print("hello.D21E.echo: you typed \"");
    buffer[index++] = chr;
    if (index == (max_buffer - 1))
      index = 0;
    SerialUSB.print(buffer);
    SerialUSB.println("\"");
  }
}

Rotary Encoder

// Rotary Encoder Inputs
#define CLK 9
#define DT 8
#define SW 10

int counter = 0;
int currentStateCLK;
int lastStateCLK;
String currentDir ="";
unsigned long lastButtonPress = 0;

void setup() {
		
	// Set encoder pins as inputs
	pinMode(CLK,INPUT);
	pinMode(DT,INPUT);
	pinMode(SW, INPUT_PULLUP);

	// Setup Serial Monitor
	SerialUSB.begin(9600);

	// Read the initial state of CLK
	lastStateCLK = digitalRead(CLK);
}

void loop() {
		
	// Read the current state of CLK
	currentStateCLK = digitalRead(CLK);

	// If last and current state of CLK are different, then pulse occurred
	// React to only 1 state change to avoid double count
	if (currentStateCLK != lastStateCLK  && currentStateCLK == 1){

		// If the DT state is different than the CLK state then
		// the encoder is rotating CCW so decrement
		if (digitalRead(DT) != currentStateCLK) {
			counter ++;
			currentDir ="CW";
		} else {
			// Encoder is rotating CW so increment
			counter --;
			currentDir ="CCW";
		}

		SerialUSB.print("Direction: ");
		SerialUSB.print(currentDir);
		SerialUSB.print(" | Counter: ");
		SerialUSB.println(counter);
	}

	// Remember last CLK state
	lastStateCLK = currentStateCLK;

	// Read the button state
	int btnState = digitalRead(SW);

	//If we detect LOW signal, button is pressed
	if (btnState == LOW) {
		//if 50ms have passed since last LOW pulse, it means that the
		//button has been pressed, released and pressed again
		if (millis() - lastButtonPress > 50) {
			SerialUSB.println("Button pressed!");
		}

		// Remember last button press event
		lastButtonPress = millis();
	}}

Capacitive Touch

#include "Adafruit_FreeTouch.h"

Adafruit_FreeTouch t6 = Adafruit_FreeTouch(2,OVERSAMPLE_64,RESISTOR_0,FREQ_MODE_NONE);
Adafruit_FreeTouch t7 = Adafruit_FreeTouch(3,OVERSAMPLE_64,RESISTOR_0,FREQ_MODE_NONE);
Adafruit_FreeTouch t8 = Adafruit_FreeTouch(4,OVERSAMPLE_64,RESISTOR_0,FREQ_MODE_NONE);
Adafruit_FreeTouch t9 = Adafruit_FreeTouch(5,OVERSAMPLE_64,RESISTOR_0,FREQ_MODE_NONE);
Adafruit_FreeTouch t10 = Adafruit_FreeTouch(6,OVERSAMPLE_64,RESISTOR_0,FREQ_MODE_NONE);

int t6min,t7min,t8min,t9min,t10min;

void setup() {
	Serial.begin(115200);  
	while (!Serial);
	t6.begin();
	t7.begin();
	t8.begin();
	t9.begin();
	t10.begin();
	t6min = t7min = t8min = t9min = t10min = 1e6;
	}

void loop() {
	int result;
	//
	// plotting scale limits
	//
	SerialUSB.print(0);
	SerialUSB.print(",");
	SerialUSB.print(300);
	SerialUSB.print(",");
	//
	// read touch
	//
	result = t6.measure();
	if (result < t6min) t6min = result;
	SerialUSB.print(result-t6min);
	SerialUSB.print(",");
	result = t7.measure();
	if (result < t7min) t7min = result;
	SerialUSB.print(result-t7min);
	SerialUSB.print(",");
	result = t8.measure();
	if (result < t8min) t8min = result;
	SerialUSB.print(result-t8min);
	SerialUSB.print(",");
	result = t9.measure();
	if (result < t9min) t9min = result;
	SerialUSB.print(result-t9min);
	SerialUSB.print(",");
	result = t10.measure();
	if (result < t10min) t10min = result;
	SerialUSB.println(result-t10min);
	//
	// pause
	//
	delay(50);
}

#include <HID-Project.h>
#include <HID-Settings.h>
#include "Adafruit_FreeTouch.h"


Adafruit_FreeTouch t0 = Adafruit_FreeTouch(2, OVERSAMPLE_64, RESISTOR_0, FREQ_MODE_NONE);
Adafruit_FreeTouch t1 = Adafruit_FreeTouch(3, OVERSAMPLE_64, RESISTOR_0, FREQ_MODE_NONE);
Adafruit_FreeTouch t2 = Adafruit_FreeTouch(4, OVERSAMPLE_64, RESISTOR_0, FREQ_MODE_NONE);
Adafruit_FreeTouch t3 = Adafruit_FreeTouch(5, OVERSAMPLE_64, RESISTOR_0, FREQ_MODE_NONE);
Adafruit_FreeTouch t4 = Adafruit_FreeTouch(6, OVERSAMPLE_64, RESISTOR_0, FREQ_MODE_NONE);

// Rotary Encoder Inputs
#define CLK 9
#define DT 8
#define SW 10

int counter = 0;
int currentStateCLK;
int lastStateCLK;
unsigned long lastButtonPress = 0;

int baseline[5] = {1e6, 1e6, 1e6, 1e6, 1e6};

void setup() {
	// Set encoder pins as inputs
	pinMode(CLK, INPUT);
	pinMode(DT, INPUT);
	pinMode(SW, INPUT_PULLUP);

	// Start USB HID (Keyboard & Consumer Control)
	Consumer.begin();
	Keyboard.begin();
	
	// Setup Serial Monitor
	SerialUSB.begin(9600);

		while (!Serial);

	// Initialize FreeTouch sensors
	t0.begin(); t1.begin(); t2.begin(); t3.begin(); t4.begin();

	// Calibrate baseline
	for (int i = 0; i < 100; i++) {
	baseline[0] = min(baseline[0], t0.measure());
	baseline[1] = min(baseline[1], t1.measure());
	baseline[2] = min(baseline[2], t2.measure());
	baseline[3] = min(baseline[3], t3.measure());
	baseline[4] = min(baseline[4], t4.measure());
	delay(10);
	}
	// Read the initial state of CLK
	lastStateCLK = digitalRead(CLK);
}

void loop() {
	// Read the current state of CLK
	currentStateCLK = digitalRead(CLK);

	// Detect rotation
	if (currentStateCLK != lastStateCLK && currentStateCLK == 1) {
		if (digitalRead(DT) != currentStateCLK) {
			// Clockwise Rotation (Increase Volume)
			counter++;
			Consumer.write(MEDIA_VOLUME_UP);
			SerialUSB.println("Volume UP");
		} else {
			// Counterclockwise Rotation (Decrease Volume)
			counter--;
			Consumer.write(MEDIA_VOLUME_DOWN);
			SerialUSB.println("Volume DOWN");
		}
	}

	// Remember last CLK state
	lastStateCLK = currentStateCLK;

	// Read the button state
	int btnState = digitalRead(SW);

	// Detect button press (Play/Pause)
	if (btnState == LOW) {
		if (millis() - lastButtonPress > 200) {  // Debounce button
			SerialUSB.println("Play/Pause");
			Consumer.write(MEDIA_PLAY_PAUSE);
		}
		lastButtonPress = millis();
	}

	int touchValues[5] = {
	t0.measure() - baseline[0],
	t1.measure() - baseline[1],
	t2.measure() - baseline[2],
	t3.measure() - baseline[3],
	t4.measure() - baseline[4]
	};

	int total = 0, weightedSum = 0;
	for (int i = 0; i < 5; i++) {
	if (touchValues[i] > 10) {  // Ignore noise
		total += touchValues[i];
		weightedSum += touchValues[i] * i;
			
	}
	
	}

if(touchValues[2]>9){
	Consumer.write(MEDIA_PLAY_PAUSE);
	SerialUSB.println("Play/Pause");
	SerialUSB.print(touchValues[2]);
	delay(1000);
}

if(touchValues[1]>9){
	Consumer.write(MEDIA_PREVIOUS);
	SerialUSB.println("Previous");
	SerialUSB.print(touchValues[1]);
	delay(1000);
}

if(touchValues[3]>9){
	Consumer.write(MEDIA_NEXT);
	SerialUSB.println("Next");
	SerialUSB.print(touchValues[3]);
	delay(1000);
}

	delay(5);  // Small delay to stabilize readings
}
									

Design Files

You can download my design files from below

• TouchNav SAMD21 Board

  Traces PNG Outline PNG Outline PNG Schematic PDF

• KiCad Files

  Download ZIP