8. Electronics Design

Because the ATTiny85 has a lot less memory capacity than the XIAO RP2040 board I used earlier to run the Snake game, because of this I had to optimize the code a lot. The following was the code I uploaded to the ATTiny:

	#include Adafruit_NeoPixel.h

	#define PIN_NEOPIXEL 1
	#define NUM_NEOPIXELS 64
	#define ROWS 8
	#define COLS 8
	#define BUTTON_PIN A2
	#define BUZZER_PIN 3
	#define MAX_SNAKE_LENGTH 32
	
	Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_NEOPIXELS, PIN_NEOPIXEL, NEO_GRB + NEO_KHZ800);
	
	struct Position {
		uint8_t x, y;
	};
	
	Position snake[MAX_SNAKE_LENGTH];
	uint8_t snakeLength = 1;
	Position apple;
	uint8_t currentDirection = 0;
	unsigned int gameSpeed = 250;  // Initial game speed is 250ms
	unsigned int Brightness = 0;
	
	void setup() {
		pinMode(BUTTON_PIN, INPUT);
		pinMode(BUZZER_PIN, OUTPUT);
		strip.begin();
		strip.show();
		strip.setBrightness(10);
		snake[0] = { COLS / 2, ROWS / 2 };
		randomSeed(analogRead(0));
		generateApple();
	}
	
	void loop() {
		unsigned int buttonRead = analogRead(BUTTON_PIN);
	
		if (buttonRead > 550 && buttonRead < 580) currentDirection = 1;       // Up
		else if (buttonRead > 630 && buttonRead < 680) currentDirection = 2;  // Down
		else if (buttonRead > 810 && buttonRead < 850) currentDirection = 3;  // Left
		else if (buttonRead > 490 && buttonRead < 520) currentDirection = 4;  // Right
		else if (buttonRead > 140 && buttonRead < 210) {                      // Select
		Brightness++;
		if (Brightness > 3) {
			Brightness = 0;
		}
		switch (Brightness) {
			case 0:
			strip.setBrightness(25);
			break;
			case 1:
			strip.setBrightness(50);
			break;
			case 2:
			strip.setBrightness(75);
			break;
			case 3:
			strip.setBrightness(100);
			break;
		}
		delay(100);
		}
	
		updateSnake(currentDirection);
		delay(gameSpeed);
	
		if (snake[0].x == apple.x && snake[0].y == apple.y) {
		if (snakeLength < MAX_SNAKE_LENGTH) {
			snakeLength++;
			playTone(1000, 200);  // Play a tone when the apple is eaten
			if (snakeLength == 5) {
			playLevelUpMelody();  // Play level-up melody exactly when reaching length 5
			gameSpeed = 150;      // Speed up the game
			}
		}
		generateApple();
		}
	
		if (checkSelfCollision()) {
		playLosingMelody();
		flashRed(3);
		restartGame();
		}
	}
	
	void updateSnake(int direction) {
		Position nextHead = snake[0];
		switch (direction) {
		case 1: nextHead.y = (nextHead.y - 1 + ROWS) % ROWS; break;
		case 2: nextHead.y = (nextHead.y + 1) % ROWS; break;
		case 3: nextHead.x = (nextHead.x - 1 + COLS) % COLS; break;
		case 4: nextHead.x = (nextHead.x + 1) % COLS; break;
		}
	
		for (int i = snakeLength - 1; i > 0; i--) {
		snake[i] = snake[i - 1];
		}
		snake[0] = nextHead;
	
		strip.clear();
		for (uint8_t i = 0; i < snakeLength; i++) {
		uint8_t idx = (i % MAX_SNAKE_LENGTH);
		strip.setPixelColor(snake[idx].y * COLS + snake[idx].x, i == 0 ? strip.Color(255, 255, 0) : (snakeLength >= 5 ? strip.Color(0, 0, 255) : strip.Color(0, 255, 0)));
		}
		strip.setPixelColor(apple.y * COLS + apple.x, strip.Color(255, 0, 0));
		strip.show();
	}
	
	void playTone(unsigned int frequency, unsigned int duration) {
		unsigned long period = 1000000L / frequency;
		unsigned long length = duration * 1000L;
		for (unsigned long i = 0; i < length; i += period) {
		digitalWrite(BUZZER_PIN, HIGH);
		delayMicroseconds(period / 2);
		digitalWrite(BUZZER_PIN, LOW);
		delayMicroseconds(period / 2);
		}
	}
	
	void playLevelUpMelody() {
		unsigned int melody[] = { 523, 587, 659, 698, 784 };         // Frequencies for C5, D5, E5, F5, G5
		unsigned int noteDurations[] = { 100, 100, 100, 100, 100 };  // Note durations in milliseconds
		for (uint8_t i = 0; i < 5; i++) {
		playTone(melody[i], noteDurations[i]);
		delay(50);  // Pause between notes
		}
	}
	
	void playLosingMelody() {
		unsigned int melody[] = { 440, 392, 349, 330, 294 };         // Frequencies for A4, G4, F4, E4, D4
		unsigned int noteDurations[] = { 200, 200, 200, 200, 200 };  // Durations for each note
		for (int i = 0; i < 5; i++) {
		playTone(melody[i], noteDurations[i]);
		delay(50);  // Pause between notes
		}
	}
	
	void flashRed(uint8_t count) {
		for (uint8_t i = 0; i < count; i++) {
		for (uint8_t j = 0; j < NUM_NEOPIXELS; j++) {
			strip.setPixelColor(j, strip.Color(255, 0, 0));
		}
		strip.show();
		delay(500);
		strip.clear();
		strip.show();
		delay(500);
		}
	}
	
	bool checkSelfCollision() {
		for (uint8_t i = 1; i < snakeLength; i++) {
		if (snake[i].x == snake[0].x && snake[i].y == snake[0].y) return true;
		}
		return false;
	}
	
	void generateApple() {
		do {
		apple.x = random(COLS);
		apple.y = random(ROWS);
		} while (isOnSnake(apple.x, apple.y));
	}
	
	bool isOnSnake(uint8_t x, uint8_t y) {
		for (uint8_t i = 0; i < snakeLength; i++) {
		if (snake[i].x == x && snake[i].y == y) return true;
		}
		return false;
	}
	
	void restartGame() {
		snakeLength = 1;
		currentDirection = 0;
		snake[0] = { COLS / 2, ROWS / 2 };
		gameSpeed = 250;  // Reset to initial speed
		generateApple();
		strip.clear();
		strip.show();
	}

As you can see, compared to the previously made snake code, this one here uses more specialized variable structures that help optimize the code a lot.

The last step is to upload the code, but we can't use the normal upload button to do it. Instead, we have to use the option "Upload Using Programmer" under the "Sketch" menu:

If everything is connected right and the code has no errors, the upload process should end briefly, and in my case result in the snake game code working perfectly!

Thank you for taking a look into my 8th week's progress!

Useful links

• Download all the CAD files shown in this proyect!
• Take a look at our group assignment!
• Return to Fab Academy