/*********
Rui Santos
Complete project details at http://randomnerdtutorials.com
Quentorres - XIAO ESP32-C3
*********/
// Load Wi-Fi library
#include <WiFi.h>
// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String outputD6State = "off";
String outputD7State = "off";
// Assign output variables to GPIO pins
const int outputD6 = D6;
const int outputD7 = D7;
// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0;
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;
void setup() {
Serial.begin(115200);
// Initialize the output variables as outputs
pinMode(outputD6, OUTPUT);
pinMode(outputD7, OUTPUT);
// Set outputs to LOW
digitalWrite(outputD6, LOW);
digitalWrite(outputD7, LOW);
// Connect to Wi-Fi network with SSID and password
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// Print local IP address and start web server
Serial.println("");
Serial.println("WiFi connected.");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
server.begin();
}
void loop(){
WiFiClient client = server.available(); // Listen for incoming clients
if (client) { // If a new client connects,
currentTime = millis();
previousTime = currentTime;
Serial.println("New Client."); // print a message out in the serial port
String currentLine = ""; // make a String to hold incoming data from the client
while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
currentTime = millis();
if (client.available()) { // if there's bytes to read from the client,
char c = client.read(); // read a byte, then
Serial.write(c); // print it out the serial monitor
header += c;
if (c == '\n') { // if the byte is a newline character
// if the current line is blank, you got two newline characters in a row.
// that's the end of the client HTTP request, so send a response:
if (currentLine.length() == 0) {
// HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
// and a content-type so the client knows what's coming, then a blank line:
client.println("HTTP/1.1 200 OK");
client.println("Content-type:text/html");
client.println("Connection: close");
client.println();
// turns the GPIOs on and off
if (header.indexOf("GET /D6/on") >= 0) {
Serial.println("GPIO D6 on");
outputD6State = "on";
digitalWrite(outputD6, HIGH);
} else if (header.indexOf("GET /D6/off") >= 0) {
Serial.println("GPIO D6 off");
outputD6State = "off";
digitalWrite(outputD6, LOW);
} else if (header.indexOf("GET /D7/on") >= 0) {
Serial.println("GPIO D7 on");
outputD7State = "on";
digitalWrite(outputD7, HIGH);
} else if (header.indexOf("GET /D7/off") >= 0) {
Serial.println("GPIO D7 off");
outputD7State = "off";
digitalWrite(outputD7, LOW);
}
// Display the HTML web page
client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
client.println(".button2 {background-color: #555555;}</style></head>");
// Web Page Heading
client.println("<body><h1>ESP32 Web Server</h1>");
// Display current state, and ON/OFF buttons for GPIO D6
client.println("<p>GPIO D6 - State " + outputD6State + "</p>");
// If the outputD6State is off, it displays the ON button
if (outputD6State=="off") {
client.println("<p><a href=\"/D6/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/D6/off\"><button class=\"button button2\">OFF</button></a></p>");
}
// Display current state, and ON/OFF buttons for GPIO D7
client.println("<p>GPIO D7 - State " + outputD7State + "</p>");
// If the outputD7State is off, it displays the ON button
if (outputD7State=="off") {
client.println("<p><a href=\"/D7/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/D7/off\"><button class=\"button button2\">OFF</button></a></p>");
}
client.println("</body></html>");
// The HTTP response ends with another blank line
client.println();
// Break out of the while loop
break;
} else { // if you got a newline, then clear currentLine
currentLine = "";
}
} else if (c != '\r') { // if you got anything else but a carriage return character,
currentLine += c; // add it to the end of the currentLine
}
}
}
// Clear the header variable
header = "";
// Close the connection
client.stop();
Serial.println("Client disconnected.");
Serial.println("");
}
}