Embedded Networking and Communications

#include "WiFi.h" // WIFI library for the access point creation 
#include "ESPAsyncWebServer.h" // Web server library 
#include <DHT.h> // DHT Library 

#define PIN 8 // Where the DHT data pin is connected
#define TYPE DHT22 // DHT sensor Type.

DHT zaid(PIN,TYPE); // Constructor

// setting the access point network credentials
const char* ssid = "zaidesp";
const char* password = "12345678@";

// Creating AsyncWebServer object on port 80
AsyncWebServer server(80);

// Creating a function to return temperature 
String readTemp() {
  return String(zaid.readTemperature());
}
// Creating function to return Humidity
String readHumi() {
  return String(zaid.readHumidity());
}
void setup(){
  // Serial port for debugging purposes
  Serial.begin(115200);
  zaid.begin();
  Serial.println();
  
  // Setting the ESP as an access point
  Serial.print("Setting AP (Access Point)…");
  // Wifi Access point constructor 
  WiFi.softAP(ssid, password);

  IPAddress IP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(IP);

// Creating HTTP get request under Temperature name on the server same will be also for the Humidity
  server.on("/temperature", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", readTemp().c_str()); // Request the data from the sensor and then fetch it as a string through the get request on the server
  });
  server.on("/humidity", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", readHumi().c_str()); // Request the data from teh sensor and fetch it as string through the get request on the server 
  });
  
  // Start server
  server.begin();
}
 
void loop(){
  
}

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClient.h>

#include <ESP8266WiFiMulti.h>
ESP8266WiFiMulti WiFiMulti;

const char* ssid = "zaidesp"; // server ssid name
const char* password = "12345678@"; // server password (WIFI)

//Server side ip and page name 
const char* serverNameTemp = "http://192.168.4.1/temperature";
const char* serverNameHumi = "http://192.168.4.1/humidity";

#include <Wire.h>
#include <U8g2lib.h> 

U8G2_SSD1306_128X64_NONAME_F_HW_I2C DISPA(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);

#define SDA 4 
#define SCL 5


String temperature;
String humidity;

unsigned long previousMillis = 0;
const long interval = 5000; 

void setup() {
  Serial.begin(115200);
  
   pinMode(SDA, OUTPUT);  
   pinMode(SCL, OUTPUT);

   Wire.setClock(100000); 
   DISPA.setBusClock(100000);
   DISPA.setI2CAddress(0x78);
   DISPA.begin();
   DISPA.setFont(u8g2_font_t0_13_tf);
   DISPA.clearBuffer();

  WiFi.begin(ssid, password); // Connecting to the server wifi 
  Serial.println("Connecting");
  while(WiFi.status() != WL_CONNECTED) { // Checking the status of the connection 
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to WiFi network with IP Address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  unsigned long currentMillis = millis();
  
  if(currentMillis - previousMillis >= interval) {
     // Check WiFi connection status
    if(WiFi.status()== WL_CONNECTED ){ 
      temperature = httpGETRequest(serverNameTemp); //get request from the server to return the temperature string value
      humidity = httpGETRequest(serverNameHumi); // get request from the srever to return the humidity string value
      Serial.println("Temperature: " + temperature + " *C - Humidity: " + humidity + " %");
      
     
  // Display functions to stage the data.
    DISPA.clearBuffer();
    DISPA.setCursor(0, 10);
    DISPA.print("Temp: ");
    DISPA.setCursor(40, 10);
    DISPA.print(temperature);
    DISPA.setCursor(0, 40);
    DISPA.print("Hum: ");
    DISPA.setCursor(40, 40);
    DISPA.print(humidity);
    DISPA.sendBuffer();
      
      // save the last HTTP GET Request
      previousMillis = currentMillis;
    }
    else {
      Serial.println("WiFi Disconnected");
    }
  }
}
// Get Request function 
String httpGETRequest(const char* serverName) {
  WiFiClient client;
  HTTPClient http;
    
  // Ip address with the page name 
  http.begin(client, serverName);
  
  // Post request and wait to hear back from the server
  int httpResponseCode = http.GET();
  
  String payload = "--"; 
  
  if (httpResponseCode>0) { // Checking the response value if there is value the request will return the value of the server
    Serial.print("HTTP Response code: ");
    Serial.println(httpResponseCode);
    payload = http.getString();
  }
  else {// No value means error in the server
    Serial.print("Error code: ");
    Serial.println(httpResponseCode);
  }
  // Free resources
  http.end();

  return payload;
}