#include <SendOnlySoftwareSerial.h>
#include <TinyWireS.h>

#define TX 1

#define I2C_PERIFERAL_ADRESS 0x4 // adress on the I2C network

#define LED_OUT A3

#define NIGHT_TRESHOLD 80
#define DIRECT_SUN_UP_TRESHOLD 1000
#define DIRECT_SUN_LOW_TRESHOLD 800
#define MIN_STATE_TIME 25000

SendOnlySoftwareSerial CustomSerial(TX);
const long A = 1000;     //Resistencia en oscuridad en KΩ
const int B = 27;        //Resistencia a la luz (10 Lux) en KΩ
const int Rc = 10;       //Resistencia calibracion en KΩ

int value, ilum;
float nextChange = 0;
bool overrideON = false;
bool buttonPressed = false;
bool lightOn = false;

void setup()
{
  CLKPR = (1<<CLKPCE);
  CLKPR = (0<<CLKPS3)|(0<<CLKPS2)|(0<<CLKPS1)|(0<<CLKPS0);
  pinMode(A2, INPUT);
  pinMode(LED_OUT, OUTPUT);
  digitalWrite(LED_OUT,LOW);
  CustomSerial.begin(9600);

  TinyWireS.begin(I2C_PERIFERAL_ADRESS);
  TinyWireS.onRequest(requestEvent);
}
int readSensor(int samples = 10){
  long value = 0;
  for(int i=0; i<samples; ++i){
    value += analogRead(A2);
    tws_delay(10);
  }
  return value/samples;
}
void loop()
{
  TinyWireS_stop_check(); // needed for the I2C Libary 
  
  value = readSensor(100);
  ilum = ((long)value*A*10)/((long)B*Rc*(1024-value));
//  CustomSerial.print("raw value: ");
//  CustomSerial.println(ilum);

  if(value>1020&&!buttonPressed){
    buttonPressed = true;
//    CustomSerial.println("Button pressed");
    overrideON = !overrideON;
    nextChange = 0;
  }
  if(value<800){
    buttonPressed = false;
  }

  if(!lightOn&& (ilum>NIGHT_TRESHOLD&&ilum<DIRECT_SUN_LOW_TRESHOLD) || overrideON){
    lightOn = true;
    CustomSerial.println('a');
  }
  else if(lightOn&& (ilum>DIRECT_SUN_UP_TRESHOLD || ilum<=NIGHT_TRESHOLD) )
  {
    lightOn = false;
    CustomSerial.println('d');
  } 
  
  if(millis()< nextChange)return;
  nextChange = millis() + MIN_STATE_TIME;
  
  if(lightOn){    
    // Light needed, turn light ON
    digitalWrite(LED_OUT,HIGH);
  }
  else{
    //light not needed, turn light OFF
    digitalWrite(LED_OUT,LOW);
  }
}
void requestEvent(){
  TinyWireS.send(lowByte(ilum));
  TinyWireS.send(highByte(ilum));
}