//Program created by Isma LB

#include <SendOnlySoftwareSerial.h>

#define TX 1
#define LED_OUT A3

#define NIGHT_TRESHOLD 80
#define DIRECT_SUN_UP_TRESHOLD 1000
#define DIRECT_SUN_LOW_TRESHOLD 800
#define MIN_STATE_TIME 25000

SendOnlySoftwareSerial CustomSerial(TX);

const long A = 1000;     //Resistence on darkness on KΩ
const int B = 27;        //Resistence on light (10 Lux) on KΩ
const int Rc = 10;       //Calibracion  resistance on KΩ

int value, ilum;
//values used for the treshold and button logic
unsigned long lastChange = 0;
bool overrideON = false;
bool buttonPressed = false;
bool lightOn = false;

void setup()
{
  //set the prescaler to 1 to run at 8MHz
  CLKPR = (1<<CLKPCE);
  CLKPR = (0<<CLKPS3)|(0<<CLKPS2)|(0<<CLKPS1)|(0<<CLKPS0);
 
  //declare pins
  pinMode(A2, INPUT);
  pinMode(LED_OUT, OUTPUT);
  digitalWrite(LED_OUT,LOW);
  
  //Initalize serial comunication
  CustomSerial.begin(9600);
}
int readSensor(int samples = 10){
  long value = 0;
  for(int i=0; i<samples; ++i){
    value += analogRead(A2);
    delay(10);
  }
  return value/samples;
}
void loop()
{
  value = readSensor(100); //read and average the sensor value 100 times
  ilum = ((long)value*A*10)/((long)B*Rc*(1024-value));

  //Check the buttonto override the sensor value
  if(value>1020&&!buttonPressed){
    buttonPressed = true;
    overrideON = !overrideON;
    lastChange = 0;
  }
  if(value<800){
    buttonPressed = false;
  }

  if(!lightOn&& (ilum>NIGHT_TRESHOLD&&ilum<DIRECT_SUN_LOW_TRESHOLD) || overrideON){
    lightOn = true;
    CustomSerial.println('a'); //Send the code for light needed 
  }
  else if(lightOn&& (ilum>DIRECT_SUN_UP_TRESHOLD || ilum<=NIGHT_TRESHOLD) )
  {
    lightOn = false;
    CustomSerial.println('d'); //Send the code for light not needed 
  }

  // Waits to make light chages least often (Not needed for networking)
  if(millis() - lastChange > MIN_STATE_TIME)return; 
  
  lastChange = millis();
  
  if(lightOn){    
    // Light needed, turn light ON
    digitalWrite(LED_OUT,HIGH);
  }
  else{
    //light not needed, turn light OFF
    digitalWrite(LED_OUT,LOW);
  }
}